魔兽世界术士常用宏，问下魔兽世界里术士常用宏都有哪些

很多朋友对于魔兽世界术士常用宏和问下魔兽世界里术士常用宏都有哪些不太懂，今天就由小编来为大家分享，希望可以帮助到大家，下面一起来看看吧！

一、魔兽世界术士宏

[3]法术石宏（原创）

/stopcasting

/cast [equipped:魔杖]射击;[equipped:圣物]极效法术石;制造法术石

/equip [modifier:shift]特效法术石; [combat,noequipped:魔杖]雷特森的魔晶手杖

说明：外服翻译过来的宏有点呆版，只能实现辨别装备法术石时使用法术石，装备魔仗时射击的功能，我原来旧贴写那个是双开法术石的宏，现在有cd了，也没换另外一个法术石的必要，所以我设想了换成魔仗的可能性。而我编这个宏的作用是没法术石时制作法术石,装备魔仗时会仍魔仗，装备了法术石时，会使用法术石驱散掉魔法后再把魔仗自动换上！（为了防止不小心按错换了魔仗上去，所以我加入语句，不在战斗中时，魔仗不会替换上去！但法术石可以随时换上去）当法术石cd冷却完成后，按alt+宏快键换回法术石。如果想用其他shift或者其他组合键，只需要修改alt为shift或其他，这样能瞬间增加自己的魔伤值，法术石头cd时也有东西可用！换上魔仗后，再次按这个宏能魔仗射击，变成魔仗射击的快键！后面那个魔仗名字可以根据自己的实际装备按shift+左键点物品代换上去！

[3]法术石宏2

/stopcasting

/cast [equipped:魔杖]射击;[equipped:圣物]极效法术石;制造法术石

/equip [noequipped:魔杖,modifier:alt]生存专家的魔杖;[modifier:ctrl]极效法术石

说明：我另外一个版本法术石头宏,有的人不喜欢把魔仗换上去,但又想有需要时随时可以换上魔仗打掉撒满的图腾,所以这个宏就应运而生,这个宏的作用是,如果你没法术石在身上，也没有魔仗装备着,按它就会自动制作法术石,装备了法术石,就使用驱散,装备了魔仗,就使用射击,当你装备的是法术石,想临时换上魔仗时,按alt+快键(或者shift,ctrl,详细自己改)就可以把魔仗换上.(魔仗名字要自己改)而按ctrl就把法术石换上去..

[3]法术石宏3

/stopcasting

/cast [equipped:魔杖,modifier:alt]射击;[equipped:圣物]极效法术石;[noequipped:圣物]制造法术石

/equip [noequipped:魔杖,modifier:alt]生存专家的魔杖;[noequipped:圣物]极效法术石

说明：我写的再一个版本法术石头宏,身上没法术石时按是制作法术石,有法术石在身上时,自动替换.换上后再按这个键就能驱散魔法,而当你想换上魔仗,可以用alt+键(ctrl或者shift也可以,自己改)实现换上魔仗,继续按alt+键可以射魔仗变成魔仗使用键~实现法术石和魔仗的一键使用和更换.

[4]拉风女王技能绑定喊话宏（旧创）

/click PetActionButton6

/stopmacro [pet:地狱猎犬/虚空行者/小鬼]

/in 3/y对<<%T>>施放诱惑~(冒心心的小宝宝，一边凉快去！oye！^^!!)

说明：宠物技能绑定控制，以前女王的诱惑和狗的法术封锁我就用公共语句绑定到同一个键，所以现在我也用新语句代替了旧语句，，也就是只要放在宠物栏同一个位置的宠物技能都可以一键控制，我意思是任何一个宠物的技能，详细自己的宠技能放那里把第一条的数字改一改就可以了。这宏带女人就诱惑目标并且喊出拉风话，换成其他的宠，就能用宠技能但不会喊错误的拉风话：in是延时命令，可以让你喊出这话时，敌人已经给你诱惑住了，想反应都反应不过来，不加in的后果是。。等于提前告诉敌人你要诱惑了ˉ-ˉ！

（提要：第一条命令还可以代替为：

/cast [pet:地狱猎犬]法术封锁;[pet:魅魔]诱惑;[pet:虚空行者]受难(等级 4);[pet:小鬼]火焰之盾(等级 5)

也就是传统的把女王的诱惑，狗的法术封锁，虚空的受难，小鬼的火焰盾，都绑定到一个键上的宏）

[5]拉风狗宠物技能绑定喊话宏（旧创）

/cast [pet:地狱猎犬]法术封锁;[pet:魅魔]诱惑;[pet:虚空行者]受难(等级 4);[pet:小鬼]火焰之盾(等级 5)

/stopmacro [pet:魅魔/虚空行者/小鬼]

/y对<<%T>>施放沉默~安静点!!~小宝宝,乖啦~^^!!)

说明：宠物技能绑定控制，女王的诱惑和狗的法术封锁绑定到同一个键，并且喊出特定召唤宠物的语言！宠物是狗就法术封锁目标并且喊话，换成其他宠时，就不会喊出话，以上只列出两个宠的绑定，按这个原理，还可以把虚空的牺牲，小鬼的火焰盾，恶魔守卫的拦截等等全部绑定到同一个键上。喊话效果同上，上一条宏用了全宠控制语句，这个就用传统一点的了，狗的喊话就没加延时命令了，因为沉默就沉默了，瞬发，人都变乖了。。给他看到喊话又能怎么样？

[6]不改变当前目标诱惑前一目标宏（应回贴要求）：

/focus [modifier:alt] target

/cast [target=focus,pet:魅魔]诱惑

/clearfocus [target=focus,dead]

说明：这个宏按alt+快键诱惑当前目标，而单独按快键就不改变当前目标的前提下诱惑前一目标！

[7]不改变当前目标诱惑前一目标宏改进版（原创）

/cast [target=focus,pet:魅魔,modifier:alt]诱惑

/clearfocus [modifier:alt,target=focus,dead]

/stopmacro [modifier:alt]

/focus target

/cast [pet:魅魔]诱惑

说明：上一个宏需要按alt+快键才能诱惑当前目标，那是外服早期翻译过来的宏，也不知道是那位达人写的，但感觉不方便，因为诱惑当前目标是用得最多的，需要按alt才能用，就没意思了。我设想能不能直接按键就能诱惑当前目标，而按alt+快键才诱惑前一目标呢？这样会方便很多,最后编写成功了。至于按alt+还是shift+或者ctrl+，就自己把宏里的alt全改成shift或者ctrl就可以了！因为只有女王用这个宠才有用，所以跟前面的宠物技能绑定宏结合到一起就变成:（下面这个是我个人正在用的宏,直接按是诱惑当前目标，按alt+宏快键就不改变当前目标的同时诱惑前一目标）：

/cast [target=focus,pet:魅魔,modifier:alt]诱惑

/clearfocus [modifier:alt,target=focus,dead]

/stopmacro [modifier:alt]

/focus target

/cast [pet:地狱猎犬]法术封锁;[pet:魅魔]诱惑;[pet:虚空行者]受难(等级 4)

/stopmacro [pet:地狱猎犬/虚空行者/小鬼]

/in 3/y对<<%T>>施放诱惑~(冒心心的小宝宝，一边凉快去！oye！^^!!)

ps：这个宏还有个特殊用法，比如说对方是贼，那么无论对手在多远，只要能看到他一眼，按宏，就算宠物因为攻击距离太远并不能攻击而女王没动作，但宠已经把变量目标定义好了，那么就算对方潜行慢慢走过来，或者消失躲掉了诱惑，但只要目标进入女王诱惑的30码范围内，按alt+宏，女王就会自动锁定前面定义过的目标变量，对隐身目标施放诱惑。。这么说大家应该明白我意思了吧？把技能名字改一下,还可以实现不改边目标的同时恐惧另一目标,或者沉默另外一目标!

{/cast [target=focus,modifier:alt]恐惧(等级 3)

/clearfocus [modifier:alt,target=focus,dead]

/stopmacro [modifier:alt]

/focus target

/cast恐惧(等级 3)

}

[8]召唤门宏（原创）

/script local C; if(GetNumRaidMembers()==0) then C="PARTY" else C="RAID" end SendChatMessage("传送<<%T>>到<<"..GetMinimapZoneText()..">>.请两名队友脱离战斗并右键点一下门后不要移动。谢谢（动了的是猪^^).", C)

/cast召唤仪式

说明：这个宏会自动选择通告频道，通知队友，要求协助拉人。拉人时会在自动选择的频道里喊出“正在传送<<目标名字>>到《你所在地区》，请傍边的两名朋友脱离战斗右键点一下门后不要动。。谢谢（动了的是猪^^)！！”这句话，至于想喊什么话，自己喜欢怎么改就怎么改罗，很多搞笑的拉人话，大家需要我也可以提供^^

[9]灵魂石绑定宏（原创）

/use [help]特效灵魂石; [target=player]特效灵魂石

/团队正在对<<%T>>灵魂绑定→黑暗中永生

/p正在对<<%T>>灵魂绑定→黑暗中永生

/cast制造灵魂石(等级 5)

说明：灵魂石宏，身上没灵魂石按一下的话就会做灵魂石。身上有灵魂石的话，就会给目标绑定灵魂！并且通知队友，拉风点可以把话改成：你已在黑暗中永生。。奉上你的灵魂。雄起！~

[10]狗解自身魔法宏：

/cast [target=player]吞噬魔法

说明：这个是pk杀人越货必用的了。可以实现当目标是敌人时,就吃掉自己身上的负面魔法,而不改变敌对目标!!

[11]狗解自身或者队友魔法智能判断宏：（原创）

/cast [modifier:alt]吞噬魔法

/stopmacro [modifier:alt]

/cast [help]吞噬魔法; [target=player]吞噬魔法

说明：这个是pk杀人越货必用的了。可以实现当目标是敌人时,就吃掉自己身上的负面魔法,而不改变敌对目标!而当目标是队友时,就会智能判断,帮助队友解除队友的负面魔法,!如果你想驱散敌人目标的增益魔法,只要按着组合键alt+宏快键,就可以消除敌对目标的有益处魔法,这个宏实现对任何情况的狗魔法应变操作!组合键我写这个是按alt+宏,如果想用shift或者ctrl,把宏中的alt改成shift或者ctrl就可以了!第三那句还可以改成/cast [target=self]就会变成无论目标是谁都会为自己解魔法，不过这个目的比较单一!还有如果不想用组合键,就可以把前两句删掉，不过删掉了，吃敌人魔法就要额外设快键了，看自己需要吧

[12]生命分流/低级生命分流宏:

#showtooltip生命分流

/cast [modifier:alt]生命分流(等级 3);生命分流(等级6)

说明：生命分流顶级的太危险了，一分就近1000的血没了，所以ss有必要使用两个不同级的分流。为了节约快键，,直接按是顶级的分流,按住Alt按是3级分流.如果想把Alt换成别的配合键，可修改[modifier:alt]中的"alt",可以改成ctrl,shift等

当然也可以用同样方法实现顶级暗蛋/1级暗蛋的合并.

[13]暗影之怒宏

#showtooltip暗影之怒

/stopcasting

/cast暗影之怒

说明：毁灭系41的天赋技能为什么需要设这个宏呢？因为我发现原技能放技能栏里，连按两下会导致施放失败，很多时候给贼晕了都需要狂按这个技能，或者放暗蛋献技后都需要不停按来达到第一时间放暗影之怒的效果，但连按会打断感觉不方便，而将这个技能设成这个宏后，就可以不打断这个技能。。当然有的人喜欢打断。。我倒不喜欢。看需要使用吧。

[14]仍瑟银手雷宏:

#showtooltip瑟银手雷

/stopcasting

/use瑟银手雷

说明：因为铁皮手雷在更新后对53级以上目标就会有几率失败而对60级的目标几乎是90%以上的失败所以基本作废了,喜欢投手雷的朋友可以换瑟银手雷玩.宏同过去的铁皮宏,使用途中按为取消.

[15]一键放dot宏（不推荐使用，除非练级需要）

/castsequence reset=combat/target腐蚀术(等级 7),献祭(等级 8),痛苦诅咒(等级 6)

说明：这个宏按了后会按技能名字顺序放出每个技能。。后面你想放什么技能，只需要加个豆号后按shift在游戏里左键点法术技能名字，就会自动加上去

[16]双开护符+技能宏:

#showtooltip痛苦诅咒

/use 14

/use 13

/cast诅咒增幅

/stopcasting

/cast痛苦诅咒(等级 6)

说明：效果等同原来以前的双开护符宏，开两个饰品+增幅诅咒+痛苦诅咒，如果不想开护符后开痛苦诅咒，可以把/use 14和/use 13去掉，这宏会显示原技能图标

[17]智能护符宏（旧创）

#showtooltip痛苦诅咒

/use赞达拉英雄护符

/stopcasting

/cast痛苦诅咒(等级 6)

说明：这个是检测性的护符连用技能宏，很久以前在2.0以前我就设想过这类宏，因为我有好几个技能好象腐蚀，暗蛋，灵魂之火都是和护符连用的，但2.0以前的语句只要放在饰品相同位置的东西就会使用，并不能检测是否装备的是护符，也就是说如果你想在原来放护符的饰品栏里放其他工程饰品，就必须把技能宏改来改去，现在不用这么麻烦的改来改去了。这种宏在2.0以前写不出来，现在倒可以用比较简单的语句实现这个功能。这个宏显示原技能的图标，并且如果你护符没装备到饰品栏里，按技能也不会错误性地使用饰品栏的工程饰品。以后不用改来改去了^^（对吟唱性技能的护符连用可以把中间那条/stopcasting去掉，防止打断施法！）

二、问下魔兽世界里术士常用宏都有哪些

恐惧

#showtooltip恐惧

/stopcasting

/cast恐惧

打断当前施法动作,使用恐惧.(该宏最大的优点体现在:当你正在使用其他吟唱法术

或者通道法术的过程当中,那么你想使用恐惧,无需你按ESC,移动一下,跳一下才能使用

恐惧,此宏能简单地让你即使正在引导施法,或者吟唱施法,直接点击就可以使用恐惧,

其他各项都采用了此宏的写法)

2坐骑

#showtooltip绿色驭风者

/stopcasting

/cast [flyable]绿色驭风者;召唤恐惧战马(召唤)

一键坐骑,回到艾泽拉斯大陆时候使用非飞行坐骑,

回到外域则使用飞行坐骑

3一键上DOT

#showtooltip痛苦无常

/stopcasting

/castsequence reset=18/combat/target痛苦无常(等级 3),腐蚀术(等级 8),生命虹吸(等级 6),痛苦诅咒(等级 7)

4增幅后的痛苦诅咒

#showtooltip痛苦诅咒

/cast诅咒增幅

/stopcasting

/cast痛苦诅咒(等级 6)

5宠物打根基图腾：

/目标根基图腾

/petattack

/cast射击

/targetlasttarget

/equip [combat]雕刻过的巫医之杖

6宠物打灼热图腾：

/目标灼热图腾

/petattack

/cast射击

/targetlasttarget

/equip [combat]雕刻过的巫医之杖

7宠物打战栗图腾：

/目标战栗图腾

/petattack

/cast射击

/targetlasttarget

/equip [combat]雕刻过的巫医之杖

8暗影灼烧

#showtooltip暗影灼烧

/stopcasting

/cast [noharm]火焰之雨(等级 1);暗影灼烧

有目标时使用暗影灼烧,无目标使用1级火雨

9恐惧

#showtooltip恐惧

/stopcasting

/cast [target=mouseover]恐惧

恐惧鼠标指向的目标,无需选中那个

10法术封锁

#showtooltip法术封锁

/stopcasting

/cast [target=mouseover]法术封锁

法术封锁鼠标指向的目标,无需选中那个

11吞噬魔法

#showtooltip吞噬魔法

/stopcasting

/cast吞噬魔法

吞噬掉选中的目标身上的一个有益魔法

12吞噬魔法

#showtooltip吞噬魔法

/stopcasting

/cast [target=player]吞噬魔法

吞噬掉自己身上的一个DEBUFF魔法,且无需选中自己,不更换目标

13诱惑

#showtooltip诱惑

/stopcasting

/cast [target=mouseover]诱惑

诱惑鼠标指向的目标,无需选中那个

14动作条翻页

/swapactionbar [翻页技] 1 2

动作条1,动作条2互换

15前距离

/console SET targetNearestDistance"36"

将“TAB”能选定目标的最远距离改为50码。(我自己选择设置的为36码)

16后距离

/console SET targetNearestDistanceRadius"36"

将“TAB”能选定身后目标的最远距离设为50码，不过并不推荐这

么做，20就够了。(我自己选择设置的为36码)

17亡灵意志

/targetlasttarget

/cast亡灵意志

被恐惧后会丢失目标，这个宏的作用就是让你在用亡灵意志的同时选定最后

一个目标，也就是刚刚丢失的那个目标。

18手雷

#showtooltip精金手雷

/stopcasting

/use精金手雷

按一下出现选定区域,再按一下打断丢手雷动作,重新选定区域

19绷带

#showtooltip厚灵纹布绷带

/stopcasting

/use [harm,target=player]厚灵纹布绷带;厚灵纹布绷带

目标不是敌对的,那么就对目标使用绷带;无目标或者目标为敌对的,那么对自己使用绷带

20语言诅咒

#showtooltip语言诅咒

/stopcasting

/cast语言诅咒(等级 2)

21灼热之痛

#showtooltip灼热之痛

/cast [modifier:alt]吸取灵魂(等级 1);灼热之痛(等级 8)

直接按使用灼热之痛,按住ALT+快捷键为吸取灵魂

22银色新月徽记

#showtooltip银色新月徽记

/use 13

/use 14

使用护符上,下两个

三、魔兽世界求几个术士的常用宏

一键DOT宏（特别提示：一键DOT宏可以根据自己的需要设置技能施放顺序及重置条件。）：

#showtooltip

/castsequence reset=target/combat/18腐蚀术,痛苦诅咒,献祭,生命虹吸

焦点沉默宏（特别提示：使用焦点沉默宏之前，请预先设置焦点目标。）：

/cast [target=focus]法术封锁

地狱猎取吃魔法宏（特别提示：该宏可以控制恶魔犬吞噬魔法。

目标队友时吞噬盟友身上魔法，没有目标或目标对方时吞噬自身魔法，按住alt键吞噬对方魔法。）：

/cast [help]吞噬魔法

/cast [target=player,nomodifier]吞噬魔法

/cast [harm,modifier:alt]吞噬魔法

焦点恐惧宏（特别提示：正在使用的焦点宏可以在不预设焦点目标的情况下使用，无焦点目标或焦点目标死亡时，会自动设置当前目标为焦点，并施放恐惧。）：

/clearfocus [target=focus,dead]

/focus target [harm, target=focus,noexists]

/cast [target=focus]恐惧

无缝魅魔宏（特别提示：MM不改变目标魅惑。魅惑第一个目标，继续按下时如果第一个目标没有死亡，继续魅惑第一个目标，期间可以随意切换目标攻击，按住alt键或第一个目标死亡，将转而魅惑当前目标。）

#showtooltip

/clearfocus [modifier:alt]

/focus [target=focus,noexists];[target=focus,dead]

/clearfocus [target=focus,help]

/petfollow

/cast [pet:魅魔,target=focus,exists,harm]诱惑

控宠打图腾宏（特别提示：该宏可以按顺序添加其他图腾的名字。）：

/target战栗图腾

/target地缚图腾

/PetAttack

/targetLASTtarget

抓贼宏（特别提示：最后的技能可以根据自己的喜好修改，建议用瞬发技能，比如痛苦诅咒或腐蚀术。）：

#showtooltip

/cleartarget

/targetenemy

/cast [harm,nodead]死亡缠绕

一键宠物宏（特别提示：一键招宠点击默认召唤魅魔，按alt+宏按键召唤小鬼，按shift召唤地狱猎犬，按ctrl键召唤虚空行者。）

#showtooltip

/cast [modifier:alt]召唤小鬼;[modifier:shift]召唤地狱猎犬;[modifier:ctrl]召唤虚空行者;召唤魅魔

手雷宏（特别提示：手雷名字可按自己需要自行替换。）

#showtooltip

/stopcasting

/use精金手雷

一键BUFF宏（特别提示：切换目标后该宏会自动重置技能施放顺序。）

#showtooltip

/castsequence reset=target魔息术,侦测潜行

优化诅咒宏（特别提示：默认对当前目标施放语言诅咒，如当前无目标则对鼠标滑过的目标施放，按alt键+宏按键施放疲劳诅咒，按shift施放厄运诅咒，按ctrl键施放元素诅咒。按键组合可根据自己的偏好进行修改。）

#showtooltip

/cast [harm,target=mouseover][mod:alt]疲劳诅咒;[mod:ctrl]元素诅咒;[mod:shift]厄运诅咒;语言诅咒

宠物技能宏（特别提示：各种宠物的常用技能。）：

/cast法术封锁

/cast魅惑

/cast牺牲

/cast火焰之盾

极效保命宏（特别提示：根据自己的战斗大师饰品和治疗石替换名字。）

/cast战斗大师之祸灭

/cast恶魔皮肤

/cast魔化治疗石

灼烧补刀宏（特别提示：同时使用手套物品（工程附魔：火箭炮）和暗影灼烧，非工程的同学可以忽略。）

/cast 10

/cast暗影灼烧

法术石宏（特别提示提示：点击直接抹法术石(强制替换当前石头效果)，shift+点击制造法术石。同理适用火焰石、灵魂石。）

#showtooltip [modifier:alt]制造法术石;极大法术石

/use极大法术石

/cast [modifier:alt]制造法术石;[button:2]制造法术石/click StaticPopup1Button1

术士输出鬼火宏：

/console Sound_EnableSFX 0

/castsequence reset=4/combat/target燃烧,献祭,烧尽,烧尽,烧尽,生命分流

/cast混乱之箭

/console Sound_EnableSFX 1

/脚本 UIErrorsFrame:Clear()

脚本：AHK脚本

$2::;

Loop

{

if not GetKeyState("2","P");

break

Send{2}

加入腐蚀术的版本：

/console Sound_EnableSFX 0

/castsequence reset=4/combat/target燃烧,献祭,烧尽,烧尽,烧尽,生命分流(等级 6)

/castsequence reset=3/combat/target混乱之箭,腐蚀术

/console Sound_EnableSFX 1

/脚本 UIErrorsFrame:Clear()

脚本：AHK脚本

$2::;

Loop

{

if not GetKeyState("2","P");

break

Send{2}

ControlSend,,{2},魔兽世界,,,

Sleep,100

}

return

ControlSend,,{2},魔兽世界,,,

Sleep,100

}

return

虽然说宏很方便但是建议还是不要用宏输出，因为宏会严重影响术士的DPS输出

还有就是真的很累，能不能多少把这个搞成个采纳答案也好啊

OK，本文到此结束，希望对大家有所帮助。